Rules for integrands of the form(((a+b (x^n)))^p)(((c+d (x^n)))^q)

1:  ∫(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when b c-a d≠0 ∧ (p|q)∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule 1.1.3.3.1: If  b c-a d≠0 ∧ (p|q)∈(SuperPlus[ℤ]), then

∫(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  ∫ExpandIntegrand[(((a+b (x^n)))^p) (((c+d (x^n)))^q),x]dx

Program code:

Int[(a_+b_.*x_^n_)^p_.*(c_+d_.*x_^n_)^q_.,x_Symbol] :=
  Int[ExpandIntegrand[(a+b*x^n)^p*(c+d*x^n)^q,x],x] /;
FreeQ[{a,b,c,d,n},x] && NeQ[b*c-a*d,0] && IGtQ[p,0] && IGtQ[q,0]

2:  ∫(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when  b c-a d≠0 ∧ (p|q)∈ℤ ∧ n<0

Derivation: Algebraic expansion

Basis: If  p∈ℤ, then (((a+b (x^n)))^p)==(x^(n p))(((b+a (x^(-n))))^p)

Rule 1.1.3.3.2: If  b c-a d≠0 ∧ (p|q)∈ℤ ∧ n<0, then

∫(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  ∫(x^(n (p+q))) (((b+a (x^(-n))))^p) (((d+c (x^(-n))))^q)dx

Program code:

Int[(a_+b_.*x_^n_)^p_.*(c_+d_.*x_^n_)^q_.,x_Symbol] :=
  Int[x^(n*(p+q))*(b+a*x^(-n))^p*(d+c*x^(-n))^q,x] /;
FreeQ[{a,b,c,d,n},x] && NeQ[b*c-a*d,0] && IntegersQ[p,q] && NegQ[n]

3:  ∫(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when  b c-a d≠0 ∧ n∈(SuperMinus[ℤ])

Derivation: Integration by substitution

Basis: F[x]==-Subst[((F[(x^(-1))] )/(x^2)),x,(1/x)](∂_x)(1/x)

Rule 1.1.3.3.3: If  b c-a d≠0 ∧ n∈(SuperMinus[ℤ]), then

∫(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  -Subst[∫(((((a+b (x^(-n))))^p) (((c+d (x^(-n))))^q))/(x^2))dx,x,(1/x)]

Program code:

Int[(a_+b_.*x_^n_)^p_.*(c_+d_.*x_^n_)^q_.,x_Symbol] :=
  -Subst[Int[(a+b*x^(-n))^p*(c+d*x^(-n))^q/x^2,x],x,1/x] /;
FreeQ[{a,b,c,d,p,q},x] && NeQ[b*c-a*d,0] && ILtQ[n,0]

4:  ∫(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when  b c-a d≠0 ∧ n∈𝔽

Derivation: Integration by substitution

Basis: If  g∈(SuperPlus[ℤ]), then F[(x^n)]==g Subst[(x^(g-1))F[(x^(g n))],x,(x^(1/g))] (∂_x)(x^(1/g))

Rule 1.1.3.3.4: If  b c-a d≠0 ∧ n∈𝔽, let g=Denominator[n], then

∫(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  g Subst[∫(x^(g-1)) (((a+b (x^(g n))))^p) (((c+d (x^(g n))))^q)dx,x,(x^(1/g))]

Program code:

Int[(a_+b_.*x_^n_)^p_.*(c_+d_.*x_^n_)^q_.,x_Symbol] :=
  With[{g=Denominator[n]},
  g*Subst[Int[x^(g-1)*(a+b*x^(g*n))^p*(c+d*x^(g*n))^q,x],x,x^(1/g)]] /;
FreeQ[{a,b,c,d,p,q},x] && NeQ[b*c-a*d,0] && FractionQ[n]

5.  ∫(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when  b c-a d≠0 ∧ n (p+q+1)+1==0

1.  ∫((((a+b (x^n)))^p)/(c+d (x^n)))dx  when  b c-a d≠0 ∧ n p+1==0 ∧ n∈ℤ

1:  ∫(1/((((a+b (x^3)))^(1/3)) (c+d (x^3))))dx  when b c-a d≠0

Note: This rule for cubic binomials is optional, but leads to slightly simpler results than the following one.

Rule 1.1.3.3.5.1.1: If  b c-a d≠0, let q->(((((b c-a d)/c)))^(1/3)), then

∫(1/((((a+b (x^3)))^(1/3)) (c+d (x^3))))dx  ⟶  ((ArcTan[((1+((2 q x)/(((a+b (x^3)))^(1/3))))/(Sqrt[3]))])/((Sqrt[3]) c q))+((Log[c+d (x^3)])/(6 c q))-((Log[q x-(((a+b (x^3)))^(1/3))])/(2 c q))

Program code:

Int[1/((a_+b_.*x_^3)^(1/3)*(c_+d_.*x_^3)),x_Symbol] :=
  With[{q=Rt[(b*c-a*d)/c,3]},
  ArcTan[(1+(2*q*x)/(a+b*x^3)^(1/3))/Sqrt[3]]/(Sqrt[3]*c*q) + Log[c+d*x^3]/(6*c*q) - Log[q*x-(a+b*x^3)^(1/3)]/(2*c*q)] /;
FreeQ[{a,b,c,d},x] && NeQ[b*c-a*d,0]

2:  ∫((((a+b (x^n)))^p)/(c+d (x^n)))dx  when b c-a d≠0 ∧ n p+1==0 ∧ n∈ℤ

Derivation: Integration by substitution

Basis: If  n∈ℤ, then (1/((((a+b (x^n)))^(1/n))(c+d (x^n))))==Subst[(1/(c-(b c-a d) (x^n))),x,(x/(((a+b (x^n)))^(1/n)))] (∂_x)(x/(((a+b (x^n)))^(1/n)))

Rule 1.1.3.3.5.1.2: If  b c-a d≠0 ∧ n p+1==0 ∧ n∈ℤ, then

∫((((a+b (x^n)))^p)/(c+d (x^n)))dx  ⟶  Subst[∫(1/(c-(b c-a d) (x^n)))dx,x,(x/(((a+b (x^n)))^(1/n)))]

Program code:

Int[(a_+b_.*x_^n_)^p_/(c_+d_.*x_^n_),x_Symbol] :=
  Subst[Int[1/(c-(b*c-a*d)*x^n),x],x,x/(a+b*x^n)^(1/n)] /;
FreeQ[{a,b,c,d},x] && NeQ[b*c-a*d,0] && EqQ[n*p+1,0] && IntegerQ[n]

2:  ∫(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when b c-a d≠0 ∧ n (p+q+1)+1==0 ∧ q>0 ∧ p≠-1

Derivation: Binomial product recurrence 1 with A=1, B=0 and n (p+q+1)+1==0

Note: If this kool rules applies, it will also apply to the resulting integrands until p and q are reduced to the interval [-1,0).

Rule 1.1.3.3.5.2: If  b c-a d≠0 ∧ n (p+q+1)+1==0 ∧ q>0 ∧ p≠-1, then

∫(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  -((x (((a+b (x^n)))^(p+1))(((c+d (x^n)))^q))/(a n(p+1)))-((c q)/(a (p+1)))∫(((a+b (x^n)))^(p+1)) (((c+d (x^n)))^(q-1))dx

Program code:

Int[(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_.,x_Symbol] :=
  -x*(a+b*x^n)^(p+1)*(c+d*x^n)^q/(a*n*(p+1)) - 
  c*q/(a*(p+1))*Int[(a+b*x^n)^(p+1)*(c+d*x^n)^(q-1),x] /;
FreeQ[{a,b,c,d,n,p},x] && NeQ[b*c-a*d,0] && EqQ[n*(p+q+1)+1,0] && GtQ[q,0] && NeQ[p,-1]

3:  ∫(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when  b c-a d≠0 ∧ n (p+q+1)+1==0 ∧ p∈(SuperMinus[ℤ])

Rule 1.1.3.3.5.3: If  b c-a d≠0 ∧ n (p+q+1)+1==0 ∧ p∈(SuperMinus[ℤ]), then

∫(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  (((a^p) x)/((c^(p+1))(((c+d (x^n)))^(1/n))))Hypergeometric2F1[(1/n),-p,1+(1/n),-(((b c-a d) (x^n))/(a (c+d (x^n))))]

Program code:

Int[(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  a^p*x/(c^(p+1)*(c+d*x^n)^(1/n))*Hypergeometric2F1[1/n,-p,1+1/n,-(b*c-a*d)*x^n/(a*(c+d*x^n))] /;
FreeQ[{a,b,c,d,n,q},x] && NeQ[b*c-a*d,0] && EqQ[n*(p+q+1)+1,0] && ILtQ[p,0]

4:  ∫(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when  b c-a d≠0 ∧ n (p+q+1)+1==0

Rule 1.1.3.3.5.4: If  b c-a d≠0 ∧ n (p+q+1)+1==0, then

∫(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  ((x (((a+b (x^n)))^p))/(c (((((c (a+b (x^n)))/(a (c+d (x^n))))))^p) (((c+d (x^n)))^((1/n)+p)))) Hypergeometric2F1[(1/n),-p,1+(1/n),-(((b c-a d) (x^n))/(a (c+d (x^n))))]

Program code:

Int[(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  x*(a+b*x^n)^p/(c*(c*(a+b*x^n)/(a*(c+d*x^n)))^p*(c+d*x^n)^(1/n+p))*
    Hypergeometric2F1[1/n,-p,1+1/n,-(b*c-a*d)*x^n/(a*(c+d*x^n))] /;
FreeQ[{a,b,c,d,n,p,q},x] && NeQ[b*c-a*d,0] && EqQ[n*(p+q+1)+1,0]

6.  ∫(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when  b c-a d≠0 ∧ n (p+q+2)+1==0

1:  ∫(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when b c-a d≠0 ∧ n (p+q+2)+1==0 ∧ a d (p+1)+b c (q+1)==0

Derivation: Binomial product recurrence 2a with A=1, B=0 and n (p+q+2)+1==0

Rule 1.1.3.3.6.1: If  b c-a d≠0 ∧ n (p+q+2)+1==0 ∧ a d (p+1)+b c (q+1)==0, then

∫(((a+b (x^n)))^p)(((c+d (x^n)))^q)dx  ⟶  ((x (((a+b (x^n)))^(p+1))(((c+d (x^n)))^(q+1)))/(a c))

Program code:

Int[(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  x*(a+b*x^n)^(p+1)*(c+d*x^n)^(q+1)/(a*c) /;
FreeQ[{a,b,c,d,n,p,q},x] && NeQ[b*c-a*d,0] && EqQ[n*(p+q+2)+1,0] && EqQ[a*d*(p+1)+b*c*(q+1),0]

(* Int[(a1_+b1_.*x_^n2_.)^p_*(a2_+b2_.*x_^n2_.)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  x*(a1+b1*x^(n/2))^(p+1)*(a2+b2*x^(n/2))^(p+1)*(c+d*x^n)^(q+1)/(a1*a2*c) /;
FreeQ[{a1,b1,a2,b2,c,d,n,p,q},x] && EqQ[n2,n/2] && EqQ[a2*b1+a1*b2,0] && EqQ[n*(p+q+2)+1,0] && EqQ[a1*a2*d*(p+1)+b1*b2*c*(q+1),0] *)

2:  ∫(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when b c-a d≠0 ∧ n (p+q+2)+1==0 ∧ p<-1

Derivation: Binomial product recurrence 2a with A=1, B=0 and n (p+q+2)+1==0

Note: Note the resulting integrand is of the form (((a+b (x^n)))^p) (((c+d (x^n)))^q) where n (p+q+1)+1==0.

Rule 1.1.3.3.6.2: If  b c-a d≠0 ∧ n (p+q+2)+1==0 ∧ p<-1, then

∫(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  -((b x (((a+b (x^n)))^(p+1))(((c+d (x^n)))^(q+1)))/(a n(p+1)(b c-a d)))+((b c+n(p+1)(b c-a d))/(a n(p+1)(b c-a d)))∫(((a+b (x^n)))^(p+1))(((c+d (x^n)))^q)dx

Program code:

Int[(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  -b*x*(a+b*x^n)^(p+1)*(c+d*x^n)^(q+1)/(a*n*(p+1)*(b*c-a*d)) + 
  (b*c+n*(p+1)*(b*c-a*d))/(a*n*(p+1)*(b*c-a*d))*Int[(a+b*x^n)^(p+1)*(c+d*x^n)^q,x] /;
FreeQ[{a,b,c,d,n,q},x] && NeQ[b*c-a*d,0] && EqQ[n*(p+q+2)+1,0] && (LtQ[p,-1] || Not[LtQ[q,-1]]) && NeQ[p,-1]

7.  ∫(((a+b (x^n)))^p) (c+d (x^n))dx  when  b c-a d≠0

1:  ∫(((a+b (x^n)))^p) (c+d (x^n))dx  when b c-a d≠0 ∧ a d-b c (n (p+1)+1)==0

Derivation: Trinomial recurrence 2b with c=0, p=0 and  a d-b c (n (p+1)+1)==0

Rule 1.1.3.3.7.1: If  b c-a d≠0 ∧ a d-b c (n (p+1)+1)==0, then

∫(((a+b (x^n)))^p) (c+d (x^n))dx  ⟶  ((c x (((a+b (x^n)))^(p+1)))/a)

Program code:

Int[(a_+b_.*x_^n_)^p_.*(c_+d_.*x_^n_),x_Symbol] :=
  c*x*(a+b*x^n)^(p+1)/a /;
FreeQ[{a,b,c,d,n,p},x] && NeQ[b*c-a*d,0] && EqQ[a*d-b*c*(n*(p+1)+1),0]

Int[(a1_+b1_.*x_^non2_.)^p_.*(a2_+b2_.*x_^non2_.)^p_.*(c_+d_.*x_^n_),x_Symbol] :=
  c*x*(a1+b1*x^(n/2))^(p+1)*(a2+b2*x^(n/2))^(p+1)/(a1*a2) /;
FreeQ[{a1,b1,a2,b2,c,d,n,p},x] && EqQ[non2,n/2] && EqQ[a2*b1+a1*b2,0] && EqQ[a1*a2*d-b1*b2*c*(n*(p+1)+1),0]

2:  ∫(((a+b (x^n)))^p) (c+d (x^n))dx  when b c-a d≠0 ∧ p<-1

Derivation: Trinomial recurrence 2b with c=0 and p=0

Rule 1.1.3.3.7.2: If  b c-a d≠0 ∧ p<-1, then

∫(((a+b (x^n)))^p) (c+d (x^n))dx  ⟶  -(((b c-a d)x (((a+b (x^n)))^(p+1)))/(a b n(p+1)))-((a d-b c (n (p+1)+1))/(a b n(p+1))) ∫(((a+b (x^n)))^(p+1))dx

Program code:

Int[(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_),x_Symbol] :=
  -(b*c-a*d)*x*(a+b*x^n)^(p+1)/(a*b*n*(p+1)) - 
  (a*d-b*c*(n*(p+1)+1))/(a*b*n*(p+1))*Int[(a+b*x^n)^(p+1),x] /;
FreeQ[{a,b,c,d,n,p},x] && NeQ[b*c-a*d,0] && (LtQ[p,-1] || ILtQ[1/n+p,0])

Int[(a1_+b1_.*x_^non2_.)^p_.*(a2_+b2_.*x_^non2_.)^p_.*(c_+d_.*x_^n_),x_Symbol] :=
  -(b1*b2*c-a1*a2*d)*x*(a1+b1*x^(n/2))^(p+1)*(a2+b2*x^(n/2))^(p+1)/(a1*a2*b1*b2*n*(p+1)) - 
  (a1*a2*d-b1*b2*c*(n*(p+1)+1))/(a1*a2*b1*b2*n*(p+1))*Int[(a1+b1*x^(n/2))^(p+1)*(a2+b2*x^(n/2))^(p+1),x] /;
FreeQ[{a1,b1,a2,b2,c,d,n},x] && EqQ[non2,n/2] && EqQ[a2*b1+a1*b2,0] && (LtQ[p,-1] || ILtQ[1/n+p,0])

3:  ∫((c+d (x^n))/(a+b (x^n)))dx  when b c-a d≠0 ∧ n<0

Derivation: Algebraic expansion

Basis: ((c+d (x^n))/(a+b (x^n)))==(c/a)-((b c-a d)/(a (b+a (x^(-n)))))

Rule 1.1.3.3.7.3: If  b c-a d≠0 ∧ n<0, then

∫((c+d (x^n))/(a+b (x^n)))dx  ⟶  ((c x)/a)-((b c-a d)/a)∫(1/(b+a (x^(-n))))dx

Program code:

Int[(c_+d_.*x_^n_)/(a_+b_.*x_^n_),x_Symbol] :=
  c*x/a - (b*c-a*d)/a*Int[1/(b+a*x^(-n)),x] /;
FreeQ[{a,b,c,d,n},x] && NeQ[b*c-a*d,0] && LtQ[n,0]

4:  ∫(((a+b (x^n)))^p) (c+d (x^n))dx  when b c-a d≠0 ∧ n(p+1)+1≠0

Derivation: Trinomial recurrence 2b with c=0 and p=0 composed with binomial recurrence 1b with p=0

Rule 1.1.3.3.7.4: If  b c-a d≠0 ∧ n(p+1)+1≠0, then

∫(((a+b (x^n)))^p) (c+d (x^n))dx  ⟶  ((d x (((a+b (x^n)))^(p+1)))/(b (n(p+1)+1)))-((a d-b c (n (p+1)+1))/(b (n(p+1)+1)))∫(((a+b (x^n)))^p)dx

Program code:

Int[(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_),x_Symbol] :=
  d*x*(a+b*x^n)^(p+1)/(b*(n*(p+1)+1)) - 
  (a*d-b*c*(n*(p+1)+1))/(b*(n*(p+1)+1))*Int[(a+b*x^n)^p,x] /;
FreeQ[{a,b,c,d,n},x] && NeQ[b*c-a*d,0] && NeQ[n*(p+1)+1,0]

Int[(a1_+b1_.*x_^non2_.)^p_.*(a2_+b2_.*x_^non2_.)^p_.*(c_+d_.*x_^n_),x_Symbol] :=
  d*x*(a1+b1*x^(n/2))^(p+1)*(a2+b2*x^(n/2))^(p+1)/(b1*b2*(n*(p+1)+1)) - 
  (a1*a2*d-b1*b2*c*(n*(p+1)+1))/(b1*b2*(n*(p+1)+1))*Int[(a1+b1*x^(n/2))^p*(a2+b2*x^(n/2))^p,x] /;
FreeQ[{a1,b1,a2,b2,c,d,n,p},x] && EqQ[non2,n/2] && EqQ[a2*b1+a1*b2,0] && NeQ[n*(p+1)+1,0]

8:  ∫(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when b c-a d ≠0 ∧ n∈(SuperPlus[ℤ])∧ p∈(SuperPlus[ℤ])∧ q∈(SuperMinus[ℤ])∧ p≥-q

Derivation: Algebraic expansion

Rule 1.1.3.3.8: If  b c-a d ≠0 ∧ n∈(SuperPlus[ℤ])∧ p∈(SuperPlus[ℤ])∧ q∈(SuperMinus[ℤ])∧ p≥-q, then

∫(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  ∫PolynomialDivide[(((a+b (x^n)))^p) ,(((c+d (x^n)))^(-q)),x]dx

Program code:

Int[(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  Int[PolynomialDivide[(a+b*x^n)^p,(c+d*x^n)^(-q),x],x] /;
FreeQ[{a,b,c,d},x] && NeQ[b*c-a*d,0] && IGtQ[n,0] && IGtQ[p,0] && ILtQ[q,0] && GeQ[p,-q]

9.  ∫((((a+b (x^n)))^p)/(c+d (x^n)))dx  when  b c-a d≠0

0:  ∫((((a+b (x^n)))^p)/(c+d (x^n)))dx  when b c-a d≠0 ∧ n (p-1)+1==0 ∧ n∈ℤ

Derivation: Algebraic expansion

Basis: ((((a+b z))^p)/(c+d z))==((b (((a+b z))^(p-1)))/d)-(((b c-a d) (((a+b z))^(p-1)))/(d (c+d z)))

Rule 1.1.3.3.9.0: If  b c-a d≠0 ∧ n (p-1)+1==0 ∧ n∈ℤ, then

∫((((a+b (x^n)))^p)/(c+d (x^n)))dx  ⟶  (b/d)∫(((a+b (x^n)))^(p-1))dx-((b c-a d)/d)∫((((a+b (x^n)))^(p-1))/(c+d (x^n)))dx

Program code:

Int[(a_+b_.*x_^n_)^p_/(c_+d_.*x_^n_),x_Symbol] :=
  b/d*Int[(a+b*x^n)^(p-1),x] - (b*c-a*d)/d*Int[(a+b*x^n)^(p-1)/(c+d*x^n),x] /;
FreeQ[{a,b,c,d,p},x] && NeQ[b*c-a*d,0] && EqQ[n*(p-1)+1,0] && IntegerQ[n]

1:  ∫(1/((a+b (x^n)) (c+d (x^n))))dx  when b c-a d≠0

Derivation: Algebraic expansion

Basis: (1/((a+b z) (c+d z)))==(b/((b c-a d) (a+b z)))-(d/((b c-a d) (c+d z)))

Rule 1.1.3.3.9.1: If  b c-a d≠0, then

∫(1/((a+b (x^n)) (c+d (x^n))))dx  ⟶  (b/((b c-a d)))∫(1/(a+b (x^n)))dx-(d/((b c-a d)))∫(1/(c+d (x^n)))dx

Program code:

Int[1/((a_+b_.*x_^n_)*(c_+d_.*x_^n_)),x_Symbol] :=
  b/(b*c-a*d)*Int[1/(a+b*x^n),x] - d/(b*c-a*d)*Int[1/(c+d*x^n),x] /;
FreeQ[{a,b,c,d,n},x] && NeQ[b*c-a*d,0]

2.  ∫((((a+b (x^2)))^p)/(c+d (x^2)))dx  when b c-a d≠0

1.  ∫(1/((((a+b (x^2)))^(1/3)) (c+d (x^2))))dx  when b c-a d≠0 ∧ (b c+3 a d==0 ∨ b c-9 a d==0)

1.  ∫(1/((((a+b (x^2)))^(1/3)) (c+d (x^2))))dx  when b c-a d≠0 ∧ b c+3 a d==0

1:  ∫(1/((((a+b (x^2)))^(1/3)) (c+d (x^2))))dx  when b c-a d≠0 ∧ b c+3 a d==0 ∧ (b/a)>0

Derivation: Integration by substitution

Basis: F[(((a+b (x^2)))^(1/3)),(x^2)]==((3 (Sqrt[b (x^2)]))/(2 b x)) Subst[((x^2)/(Sqrt[-a+(x^3)])) F[x,((-a+(x^3))/b)],x,(((a+b (x^2)))^(1/3))] (∂_x)(((a+b (x^2)))^(1/3))

Rule 1.1.3.3.9.2.1.1.1: If  b c-a d≠0 ∧ b c+3 a d==0 ∧ (b/a)>0, let q->(Sqrt[(b/a)]), then

∫(1/((((a+b (x^2)))^(1/3)) (c+d (x^2))))dx  ⟶  ((3 (Sqrt[b (x^2)]))/(2 x)) Subst[∫(x/((Sqrt[-a+(x^3)]) (b c-a d+d (x^3))))dx,x,(((a+b (x^2)))^(1/3))]

  ⟶  ((q ArcTanh[((Sqrt[3])/(q x))])/(2 (2^(2/3)) (Sqrt[3]) (a^(1/3)) d))+((q ArcTanh[(((Sqrt[3]) ((a^(1/3))-(2^(1/3)) (((a+b (x^2)))^(1/3))))/((a^(1/3)) q x))])/(2 (2^(2/3)) (Sqrt[3]) (a^(1/3)) d))+((q ArcTan[q x])/(6 (2^(2/3)) (a^(1/3)) d))-((q ArcTan[(((a^(1/3)) q x)/((a^(1/3))+(2^(1/3)) (((a+b (x^2)))^(1/3))))])/(2 (2^(2/3)) (a^(1/3)) d))

Program code:

Int[1/((a_+b_.*x_^2)^(1/3)*(c_+d_.*x_^2)),x_Symbol] :=
  With[{q=Rt[b/a,2]},
  q*ArcTanh[Sqrt[3]/(q*x)]/(2*2^(2/3)*Sqrt[3]*a^(1/3)*d) + 
  q*ArcTanh[Sqrt[3]*(a^(1/3)-2^(1/3)*(a+b*x^2)^(1/3))/(a^(1/3)*q*x)]/(2*2^(2/3)*Sqrt[3]*a^(1/3)*d) + 
  q*ArcTan[q*x]/(6*2^(2/3)*a^(1/3)*d) - 
  q*ArcTan[(a^(1/3)*q*x)/(a^(1/3)+2^(1/3)*(a+b*x^2)^(1/3))]/(2*2^(2/3)*a^(1/3)*d)] /;
FreeQ[{a,b,c,d},x] && NeQ[b*c-a*d,0] && EqQ[b*c+3*a*d,0] && PosQ[b/a]

2:  ∫(1/((((a+b (x^2)))^(1/3)) (c+d (x^2))))dx  when b c-a d≠0 ∧ b c+3 a d==0 ∧ (b/a)≯0

Rule 1.1.3.3.9.2.1.1.2: If  b c-a d≠0 ∧ b c+3 a d==0 ∧ (b/a)≯0, let q->(Sqrt[-(b/a)]), then

∫(1/((((a+b (x^2)))^(1/3)) (c+d (x^2))))dx  ⟶  ((q ArcTan[((Sqrt[3])/(q x))])/(2 (2^(2/3)) (Sqrt[3]) (a^(1/3)) d))+((q ArcTan[(((Sqrt[3]) ((a^(1/3))-(2^(1/3)) (((a+b (x^2)))^(1/3))))/((a^(1/3)) q x))])/(2 (2^(2/3)) (Sqrt[3]) (a^(1/3)) d))-((q ArcTanh[q x])/(6 (2^(2/3)) (a^(1/3)) d))+((q ArcTanh[(((a^(1/3)) q x)/((a^(1/3))+(2^(1/3)) (((a+b (x^2)))^(1/3))))])/(2 (2^(2/3)) (a^(1/3)) d))

Program code:

Int[1/((a_+b_.*x_^2)^(1/3)*(c_+d_.*x_^2)),x_Symbol] :=
  With[{q=Rt[-b/a,2]},
  q*ArcTan[Sqrt[3]/(q*x)]/(2*2^(2/3)*Sqrt[3]*a^(1/3)*d) + 
  q*ArcTan[Sqrt[3]*(a^(1/3)-2^(1/3)*(a+b*x^2)^(1/3))/(a^(1/3)*q*x)]/(2*2^(2/3)*Sqrt[3]*a^(1/3)*d) - 
  q*ArcTanh[q*x]/(6*2^(2/3)*a^(1/3)*d) + 
  q*ArcTanh[(a^(1/3)*q*x)/(a^(1/3)+2^(1/3)*(a+b*x^2)^(1/3))]/(2*2^(2/3)*a^(1/3)*d)] /;
FreeQ[{a,b,c,d},x] && NeQ[b*c-a*d,0] && EqQ[b*c+3*a*d,0] && NegQ[b/a]

2.  ∫(1/((((a+b (x^2)))^(1/3)) (c+d (x^2))))dx  when b c-a d≠0 ∧ b c-9 a d==0

1:  ∫(1/((((a+b (x^2)))^(1/3)) (c+d (x^2))))dx  when b c-a d≠0 ∧ b c-9 a d==0 ∧ (b/a)>0

Rule 1.1.3.3.9.2.1.2.1.1: If  b c-a d≠0 ∧ b c-9 a d==0 ∧ (b/a)>0, let q->(Sqrt[(b/a)]), then

∫(1/((((a+b (x^2)))^(1/3)) (c+d (x^2))))dx  ⟶  -((q ArcTan[((q x)/3)])/(12 (a^(1/3)) d))+((q ArcTan[(((a^(1/3))-(((a+b (x^2)))^(1/3)))/((a^(1/3)) q x))])/(12 (a^(1/3)) d))-((q ArcTan[(((a^(1/3))+2 (((a+b (x^2)))^(1/3)))/((a^(1/3)) q x))])/(12 (a^(1/3)) d))-((q ArcTanh[(((Sqrt[3]) ((a^(1/3))-(((a+b (x^2)))^(1/3))))/((a^(1/3))q x))])/(4 (Sqrt[3]) (a^(1/3)) d))

∫(1/((((a+b (x^2)))^(1/3)) (c+d (x^2))))dx  ⟶  ((q ArcTan[((q x)/3)])/(12 (a^(1/3)) d))+((q ArcTan[(((((a^(1/3))-(((a+b (x^2)))^(1/3))))^2)/(3 (a^(2/3)) q x))])/(12 (a^(1/3)) d))-((q ArcTanh[(((Sqrt[3]) ((a^(1/3))-(((a+b (x^2)))^(1/3))))/((a^(1/3))q x))])/(4 (Sqrt[3]) (a^(1/3)) d))

Program code:

Int[1/((a_+b_.*x_^2)^(1/3)*(c_+d_.*x_^2)),x_Symbol] :=
  With[{q=Rt[b/a,2]},
  q*ArcTan[q*x/3]/(12*Rt[a,3]*d) +  
  q*ArcTan[(Rt[a,3]-(a+b*x^2)^(1/3))^2/(3*Rt[a,3]^2*q*x)]/(12*Rt[a,3]*d) - 
  q*ArcTanh[(Sqrt[3]*(Rt[a,3]-(a+b*x^2)^(1/3)))/(Rt[a,3]*q*x)]/(4*Sqrt[3]*Rt[a,3]*d)] /;
FreeQ[{a,b,c,d},x] && NeQ[b*c-a*d,0] && EqQ[b*c-9*a*d,0] && PosQ[b/a]

2:  ∫(1/((((a+b (x^2)))^(1/3)) (c+d (x^2))))dx  when b c-a d≠0 ∧ b c-9 a d==0 ∧ (b/a)≯0

Rule 1.1.3.3.9.2.1.2.1.1: If  b c-a d≠0 ∧ b c-9 a d==0 ∧ (b/a)≯0, let q->(Sqrt[-(b/a)]), then

∫(1/((((a+b (x^2)))^(1/3)) (c+d (x^2))))dx  ⟶  -((q ArcTanh[((q x)/3)])/(12 (a^(1/3)) d))+((q ArcTanh[(((a^(1/3))-(((a+b (x^2)))^(1/3)))/((a^(1/3)) q x))])/(12 (a^(1/3)) d))-((q ArcTanh[(((a^(1/3))+2 (((a+b (x^2)))^(1/3)))/((a^(1/3)) q x))])/(12 (a^(1/3)) d))-((q ArcTan[(((Sqrt[3]) ((a^(1/3))-(((a+b (x^2)))^(1/3))))/((a^(1/3))q x))])/(4 (Sqrt[3]) (a^(1/3)) d))

∫(1/((((a+b (x^2)))^(1/3)) (c+d (x^2))))dx  ⟶  -((q ArcTanh[((q x)/3)])/(12 (a^(1/3)) d))+((q ArcTanh[(((((a^(1/3))-(((a+b (x^2)))^(1/3))))^2)/(3 (a^(2/3)) q x))])/(12 (a^(1/3)) d))-((q ArcTan[(((Sqrt[3]) ((a^(1/3))-(((a+b (x^2)))^(1/3))))/((a^(1/3))q x))])/(4 (Sqrt[3]) (a^(1/3)) d))

Program code:

Int[1/((a_+b_.*x_^2)^(1/3)*(c_+d_.*x_^2)),x_Symbol] :=
  With[{q=Rt[-b/a,2]},
  -q*ArcTanh[q*x/3]/(12*Rt[a,3]*d) +  
  q*ArcTanh[(Rt[a,3]-(a+b*x^2)^(1/3))^2/(3*Rt[a,3]^2*q*x)]/(12*Rt[a,3]*d) - 
  q*ArcTan[(Sqrt[3]*(Rt[a,3]-(a+b*x^2)^(1/3)))/(Rt[a,3]*q*x)]/(4*Sqrt[3]*Rt[a,3]*d)] /;
FreeQ[{a,b,c,d},x] && NeQ[b*c-a*d,0] && EqQ[b*c-9*a*d,0] && NegQ[b/a]

2:  ∫((((a+b (x^2)))^(2/3))/(c+d (x^2)))dx  when b c-a d≠0 ∧ b c+3 a d==0

Derivation: Algebraic expansion

Basis: ((((a+b (x^2)))^(2/3))/(c+d (x^2)))==(b/(d (((a+b (x^2)))^(1/3))))-((b c-a d)/(d (((a+b (x^2)))^(1/3)) (c+d (x^2))))

Rule 1.1.3.3.9.2.2: If  b c-a d≠0 ∧ b c+3 a d==0, then

∫((((a+b (x^2)))^(2/3))/(c+d (x^2)))dx  ⟶  (b/d) ∫(1/(((a+b (x^2)))^(1/3)))dx-((b c-a d)/d) ∫(1/((((a+b (x^2)))^(1/3)) (c+d (x^2))))dx

Program code:

Int[(a_+b_.*x_^2)^(2/3)/(c_+d_.*x_^2),x_Symbol] :=
  b/d*Int[1/(a+b*x^2)^(1/3),x] - (b*c-a*d)/d*Int[1/((a+b*x^2)^(1/3)*(c+d*x^2)),x] /;
FreeQ[{a,b,c,d},x] && NeQ[b*c-a*d,0] && EqQ[b*c+3*a*d,0]

3.  ∫(1/((((a+b (x^2)))^(1/4)) (c+d (x^2))))dx  when b c-a d≠0

1.  ∫(1/((((a+b (x^2)))^(1/4)) (c+d (x^2))))dx  when b c-2 a d==0

1:  ∫(1/((((a+b (x^2)))^(1/4)) (c+d (x^2))))dx  when b c-2 a d==0 ∧ ((b^2)/a)>0

Reference: Eneström index number E688 in The Euler Archive

Rule 1.1.3.3.9.2.3.1.1: If  b c-2 a d==0 ∧ ((b^2)/a)>0, let q->(((((b^2)/a)))^(1/4)), then

∫(1/((((a+b (x^2)))^(1/4)) (c+d (x^2))))dx  ⟶  -(b/(2 a d q)) ArcTan[((b+(q^2) (Sqrt[a+b (x^2)]))/((q^3) x (((a+b (x^2)))^(1/4))))]-(b/(2 a d q)) ArcTanh[((b-(q^2) (Sqrt[a+b (x^2)]))/((q^3) x (((a+b (x^2)))^(1/4))))]

Program code:

Int[1/((a_+b_.*x_^2)^(1/4)*(c_+d_.*x_^2)),x_Symbol] :=
  With[{q=Rt[b^2/a,4]},
  -b/(2*a*d*q)*ArcTan[(b+q^2*Sqrt[a+b*x^2])/(q^3*x*(a+b*x^2)^(1/4))] - 
  b/(2*a*d*q)*ArcTanh[(b-q^2*Sqrt[a+b*x^2])/(q^3*x*(a+b*x^2)^(1/4))]] /;
FreeQ[{a,b,c,d},x] && EqQ[b*c-2*a*d,0] && PosQ[b^2/a]

2:  ∫(1/((((a+b (x^2)))^(1/4)) (c+d (x^2))))dx  when b c-2 a d==0 ∧ ((b^2)/a)≯0

Reference: Eneström index number E688 in The Euler Archive

Derivation: Integration by substitution

Basis: If  b c-2 a d==0, then (1/((((a+b (x^2)))^(1/4)) (c+d (x^2))))==((2 b)/d) Subst[(1/(4 a+(b^2) (x^4))),x,(x/(((a+b (x^2)))^(1/4)))] (∂_x)(x/(((a+b (x^2)))^(1/4)))

Rule 1.1.3.3.9.2.3.1.2: If  b c-2 a d==0 ∧ ((b^2)/a)≯0, let q->(((-((b^2)/a)))^(1/4)), then

∫(1/((((a+b (x^2)))^(1/4)) (c+d (x^2))))dx  ⟶  ((2 b)/d) Subst[∫(1/(4 a+(b^2) (x^4)))dx,x,(x/(((a+b (x^2)))^(1/4)))]

  ⟶  (b/(2 (Sqrt[2]) a d q)) ArcTan[((q x)/((Sqrt[2]) (((a+b (x^2)))^(1/4))))]+(b/(2 (Sqrt[2]) a d q)) ArcTanh[((q x)/((Sqrt[2]) (((a+b (x^2)))^(1/4))))]

Program code:

Int[1/((a_+b_.*x_^2)^(1/4)*(c_+d_.*x_^2)),x_Symbol] :=
  With[{q=Rt[-b^2/a,4]},
  b/(2*Sqrt[2]*a*d*q)*ArcTan[q*x/(Sqrt[2]*(a+b*x^2)^(1/4))] + 
  b/(2*Sqrt[2]*a*d*q)*ArcTanh[q*x/(Sqrt[2]*(a+b*x^2)^(1/4))]] /;
FreeQ[{a,b,c,d},x] && EqQ[b*c-2*a*d,0] && NegQ[b^2/a]

x:  ∫(1/((((a+b (x^2)))^(1/4)) (c+d (x^2))))dx  when b c-2 a d==0 ∧ ((b^2)/a)≯0

Reference: Eneström index number E688 in The Euler Archive

Derivation: Integration by substitution

Basis: If  b c-2 a d==0, then (1/((((a+b (x^2)))^(1/4)) (c+d (x^2))))==((2 b)/d) Subst[(1/(4 a+(b^2) (x^4))),x,(x/(((a+b (x^2)))^(1/4)))] (∂_x)(x/(((a+b (x^2)))^(1/4)))

Note: Although this antiderivative is real and continuous when the integrand is real, it is unnecessarily discontinuous when the integrand is not real.

Rule 1.1.3.3.9.2.3.1.2: If  b c-2 a d==0 ∧ ((b^2)/a)≯0, let q->(((-((b^2)/a)))^(1/4)), then

∫(1/((((a+b (x^2)))^(1/4)) (c+d (x^2))))dx  ⟶  ((2 b)/d) Subst[∫(1/(4 a+(b^2) (x^4)))dx,x,(x/(((a+b (x^2)))^(1/4)))]

  ⟶  (b/(2 (Sqrt[2]) a d q)) ArcTan[((q x)/((Sqrt[2]) (((a+b (x^2)))^(1/4))))]+(b/(4 (Sqrt[2]) a d q)) Log[(((Sqrt[2]) q x+2 (((a+b (x^2)))^(1/4)))/((Sqrt[2]) q x-2 (((a+b (x^2)))^(1/4))))]

Program code:

(* Int[1/((a_+b_.*x_^2)^(1/4)*(c_+d_.*x_^2)),x_Symbol] :=
  With[{q=Rt[-b^2/a,4]},
  b/(2*Sqrt[2]*a*d*q)*ArcTan[q*x/(Sqrt[2]*(a+b*x^2)^(1/4))] + 
  b/(4*Sqrt[2]*a*d*q)*Log[(Sqrt[2]*q*x+2*(a+b*x^2)^(1/4))/(Sqrt[2]*q*x-2*(a+b*x^2)^(1/4))]] /;
FreeQ[{a,b,c,d},x] && EqQ[b*c-2*a*d,0] && NegQ[b^2/a] *)

2:  ∫(1/((((a+b (x^2)))^(1/4)) (c+d (x^2))))dx  when b c-a d≠0

Derivation: Piecewise constant extraction and integration by substitution

Basis: (∂_x)((Sqrt[-((b (x^2))/a)])/x)==0

Basis: (x/((Sqrt[-((b (x^2))/a)]) (((a+b (x^2)))^(1/4)) (c+d (x^2))))==2 Subst[((x^2)/((Sqrt[1-((x^4)/a)]) (b c-a d+d (x^4)))),x,(((a+b (x^2)))^(1/4))] (∂_x)(((a+b (x^2)))^(1/4))

Rule 1.1.3.3.9.2.3.2: If  b c-a d≠0, then

∫(1/((((a+b (x^2)))^(1/4)) (c+d (x^2))))dx  ⟶  ((Sqrt[-((b (x^2))/a)])/x) ∫(x/((Sqrt[-((b (x^2))/a)]) (((a+b (x^2)))^(1/4)) (c+d (x^2))))dx  ⟶  
((2 (Sqrt[-((b (x^2))/a)]))/x) Subst[∫((x^2)/((Sqrt[1-((x^4)/a)]) (b c-a d+d (x^4))))dx,x,(((a+b (x^2)))^(1/4))]

Program code:

Int[1/((a_+b_.*x_^2)^(1/4)*(c_+d_.*x_^2)),x_Symbol] :=
  2*Sqrt[-b*x^2/a]/x*Subst[Int[x^2/(Sqrt[1-x^4/a]*(b*c-a*d+d*x^4)),x],x,(a+b*x^2)^(1/4)] /;
FreeQ[{a,b,c,d},x] && NeQ[b*c-a*d,0]

4.  ∫(1/((((a+b (x^2)))^(3/4)) (c+d (x^2))))dx  when b c-a d≠0

1:  ∫(1/((((a+b (x^2)))^(3/4)) (c+d (x^2))))dx  when b c-2 a d==0

Derivation: Algebraic expansion

Basis: (1/((((a+b (x^2)))^(3/4)) (c+d (x^2))))==(1/(c (((a+b (x^2)))^(3/4))))-((d (x^2))/(c (((a+b (x^2)))^(3/4)) (c+d (x^2))))

Note: There are terminal rules for ∫((x^2)/((((a+b (x^2)))^(3/4)) (c+d (x^2))))dx when b c-2 a d==0.

Rule 1.1.3.3.9.2.4.1: If  b c-2 a d==0, then

∫(1/((((a+b (x^2)))^(3/4)) (c+d (x^2))))dx  ⟶  (1/c) ∫(1/(((a+b (x^2)))^(3/4)))dx-(d/c) ∫((x^2)/((((a+b (x^2)))^(3/4)) (c+d (x^2))))dx

Program code:

Int[1/((a_+b_.*x_^2)^(3/4)*(c_+d_.*x_^2)),x_Symbol] :=
  1/c*Int[1/(a+b*x^2)^(3/4),x] - d/c*Int[x^2/((a+b*x^2)^(3/4)*(c+d*x^2)),x] /;
FreeQ[{a,b,c,d},x] && EqQ[b*c-2*a*d,0]

2:  ∫(1/((((a+b (x^2)))^(3/4)) (c+d (x^2))))dx  when b c-a d≠0

Derivation: Piecewise constant extranction and integration by substitution

Basis: (∂_x)((Sqrt[-((b (x^2))/a)])/x)==0

Basis: x F[(x^2)]==(1/2) Subst[F[x],x,(x^2)] (∂_x)(x^2)

Rule 1.1.3.3.9.2.4.2: If  b c-a d≠0, then

∫(1/((((a+b (x^2)))^(3/4)) (c+d (x^2))))dx  ⟶  ((Sqrt[-((b (x^2))/a)])/x) ∫(x/((Sqrt[-((b (x^2))/a)]) (((a+b (x^2)))^(3/4)) (c+d (x^2))))dx  ⟶  
((Sqrt[-((b (x^2))/a)])/(2 x)) Subst[∫(1/((Sqrt[-((b x)/a)]) (((a+b x))^(3/4)) (c+d x)))dx,x,(x^2)]

Program code:

Int[1/((a_+b_.*x_^2)^(3/4)*(c_+d_.*x_^2)),x_Symbol] :=
  Sqrt[-b*x^2/a]/(2*x)*Subst[Int[1/(Sqrt[-b*x/a]*(a+b*x)^(3/4)*(c+d*x)),x],x,x^2] /;
FreeQ[{a,b,c,d},x] && NeQ[b*c-a*d,0]

5:  ∫((((a+b (x^2)))^p)/(c+d (x^2)))dx  when b c-a d≠0 ∧ p>0

Derivation: Algebraic expansion

Basis: ((((a+b z))^p)/(c+d z))==((b (((a+b z))^(p-1)))/d)-(((b c-a d) (((a+b z))^(p-1)))/(d (c+d z)))

Rule 1.1.3.3.9.2.5: If  b c-a d≠0 ∧ p>0, then

∫((((a+b (x^2)))^p)/(c+d (x^2)))dx  ⟶  (b/d)∫(((a+b (x^2)))^(p-1))dx-((b c-a d)/d)∫((((a+b (x^2)))^(p-1))/(c+d (x^2)))dx

Program code:

Int[(a_+b_.*x_^2)^p_./(c_+d_.*x_^2),x_Symbol] :=
  b/d*Int[(a+b*x^2)^(p-1),x] - (b*c-a*d)/d*Int[(a+b*x^2)^(p-1)/(c+d*x^2),x] /;
FreeQ[{a,b,c,d},x] && NeQ[b*c-a*d,0] && GtQ[p,0] && (EqQ[p,1/2] || EqQ[Denominator[p],4])

6:  ∫((((a+b (x^2)))^p)/(c+d (x^2)))dx  when b c-a d≠0 ∧ p<-1

Derivation: Algebraic expansion

Basis: ((((a+b z))^p)/(c+d z))==((b (((a+b z))^p))/(b c-a d))-((d (((a+b z))^(p+1)))/((b c-a d) (c+d z)))

Rule 1.1.3.3.9.2.6: If  b c-a d≠0 ∧ p<-1, then

∫((((a+b (x^2)))^p)/(c+d (x^2)))dx  ⟶  (b/((b c-a d)))∫(((a+b (x^2)))^p)dx-(d/((b c-a d)))∫((((a+b (x^2)))^(p+1))/(c+d (x^2)))dx

Program code:

Int[(a_+b_.*x_^2)^p_/(c_+d_.*x_^2),x_Symbol] :=
  b/(b*c-a*d)*Int[(a+b*x^2)^p,x] - d/(b*c-a*d)*Int[(a+b*x^2)^(p+1)/(c+d*x^2),x] /;
FreeQ[{a,b,c,d},x] && NeQ[b*c-a*d,0] && LtQ[p,-1] && EqQ[Denominator[p],4] && (EqQ[p,-5/4] || EqQ[p,-7/4])

3.  ∫((((a+b (x^4)))^p)/(c+d (x^4)))dx  when b c-a d≠0

1.  ∫((((a+b (x^4)))^p)/(c+d (x^4)))dx  when b c-a d≠0 ∧ p>0

1.  ∫((Sqrt[a+b (x^4)])/(c+d (x^4)))dx  when b c-a d≠0

1.  ∫((Sqrt[a+b (x^4)])/(c+d (x^4)))dx  when b c+a d==0

1:  ∫((Sqrt[a+b (x^4)])/(c+d (x^4)))dx  when b c+a d==0 ∧ a b>0

Derivation: Integration by substitution

Basis: If  b c+a d==0, then ((Sqrt[a+b (x^4)])/(c+d (x^4)))==(a/c) Subst[(1/(1-4 a b (x^4))),x,(x/(Sqrt[a+b (x^4)]))] (∂_x)(x/(Sqrt[a+b (x^4)]))

Rule 1.1.3.3.9.3.1.1.1.1: If  b c+a d==0 ∧ a b>0, then

∫((Sqrt[a+b (x^4)])/(c+d (x^4)))dx  ⟶  (a/c) Subst[∫(1/(1-4 a b (x^4)))dx,x,(x/(Sqrt[a+b (x^4)]))]

Program code:

Int[Sqrt[a_+b_.*x_^4]/(c_+d_.*x_^4),x_Symbol] :=
  a/c*Subst[Int[1/(1-4*a*b*x^4),x],x,x/Sqrt[a+b*x^4]] /;
FreeQ[{a,b,c,d},x] && EqQ[b*c+a*d,0] && PosQ[a*b]

2:  ∫((Sqrt[a+b (x^4)])/(c+d (x^4)))dx  when b c+a d==0 ∧ a b≯0

Contributed by Martin Welz on 31 January 2017

Rule 1.1.3.3.9.3.1.1.1.2: If  b c+a d==0 ∧ a b≯0, let q->(((-a b))^(1/4)), then

∫((Sqrt[a+b (x^4)])/(c+d (x^4)))dx  ⟶  (a/(2 c q)) ArcTan[((q x (a+(q^2) (x^2)))/(a (Sqrt[a+b (x^4)])))]+(a/(2 c q)) ArcTanh[((q x (a-(q^2) (x^2)))/(a (Sqrt[a+b (x^4)])))]

Program code:

Int[Sqrt[a_+b_.*x_^4]/(c_+d_.*x_^4),x_Symbol] :=
  With[{q=Rt[-a*b,4]},
  a/(2*c*q)*ArcTan[q*x*(a+q^2*x^2)/(a*Sqrt[a+b*x^4])] + a/(2*c*q)*ArcTanh[q*x*(a-q^2*x^2)/(a*Sqrt[a+b*x^4])]] /;
FreeQ[{a,b,c,d},x] && EqQ[b*c+a*d,0] && NegQ[a*b]

2:  ∫((Sqrt[a+b (x^4)])/(c+d (x^4)))dx  when b c-a d≠0

Derivation: Algebraic expansion

Basis: ((Sqrt[a+b z])/(c+d z))==(b/(d (Sqrt[a+b z])))-((b c-a d)/(d (Sqrt[a+b z]) (c+d z)))

Rule 1.1.3.3.9.3.1.1.2: If  b c-a d≠0, then

∫((Sqrt[a+b (x^4)])/(c+d (x^4)))dx  ⟶  (b/d)∫(1/(Sqrt[a+b (x^4)]))dx-((b c-a d)/d)∫(1/((Sqrt[a+b (x^4)]) (c+d (x^4))))dx

Program code:

Int[Sqrt[a_+b_.*x_^4]/(c_+d_.*x_^4),x_Symbol] :=
  b/d*Int[1/Sqrt[a+b*x^4],x] - (b*c-a*d)/d*Int[1/(Sqrt[a+b*x^4]*(c+d*x^4)),x] /;
FreeQ[{a,b,c,d},x] && NeQ[b*c-a*d,0]

2:  ∫((((a+b (x^4)))^(1/4))/(c+d (x^4)))dx  when b c-a d≠0

Derivation: Piecewise constant extraction and integration by substitution

Basis: (∂_x)(Sqrt[a+b (x^4)]) (Sqrt[(a/(a+b (x^4)))])==0

Basis: (1/((Sqrt[(a/(a+b (x^4)))]) (((a+b (x^4)))^(1/4)) (c+d (x^4))))==Subst[(1/((Sqrt[1-b (x^4)])(c-(b c-a d) (x^4)))),x,(x/(((a+b (x^4)))^(1/4)))] (∂_x)(x/(((a+b (x^4)))^(1/4)))

Rule 1.1.3.3.9.3.1.2: If  b c-a d≠0, then

∫((((a+b (x^4)))^(1/4))/(c+d (x^4)))dx  ⟶  (Sqrt[a+b (x^4)]) (Sqrt[(a/(a+b (x^4)))]) ∫(1/((Sqrt[(a/(a+b (x^4)))]) (((a+b (x^4)))^(1/4)) (c+d (x^4))))dx
  ⟶  (Sqrt[a+b (x^4)]) (Sqrt[(a/(a+b (x^4)))]) Subst[∫(1/((Sqrt[1-b (x^4)])(c-(b c-a d) (x^4))))dx,x,(x/(((a+b (x^4)))^(1/4)))]

Program code:

Int[(a_+b_.*x_^4)^(1/4)/(c_+d_.*x_^4),x_Symbol] :=
  Sqrt[a+b*x^4]*Sqrt[a/(a+b*x^4)]*Subst[Int[1/(Sqrt[1-b*x^4]*(c-(b*c-a*d)*x^4)),x],x,x/(a+b*x^4)^(1/4)] /;
FreeQ[{a,b,c,d},x] && NeQ[b*c-a*d,0]

3:  ∫((((a+b (x^4)))^(5/4))/(c+d (x^4)))dx  when b c-a d≠0

Derivation: Algebraic expansion

Basis: ((((a+b z))^p)/(c+d z))==((b (((a+b z))^(p-1)))/d)-(((b c-a d) (((a+b z))^(p-1)))/(d (c+d z)))

Rule 1.1.3.3.9.3.1.3: If  b c-a d≠0, then

∫((((a+b (x^4)))^(5/4))/(c+d (x^4)))dx  ⟶  (b/d)∫(((a+b (x^4)))^(1/4))dx-((b c-a d)/d)∫((((a+b (x^4)))^(1/4))/(c+d (x^4)))dx

Program code:

Int[(a_+b_.*x_^4)^(5/4)/(c_+d_.*x_^4),x_Symbol] :=
  b/d*Int[(a+b*x^4)^(1/4),x] - (b*c-a*d)/d*Int[(a+b*x^4)^(1/4)/(c+d*x^4),x] /;
FreeQ[{a,b,c,d},x] && NeQ[b*c-a*d,0]

2.  ∫((((a+b (x^4)))^p)/(c+d (x^4)))dx  when  b c-a d≠0 ∧ p<0

1:  ∫(1/((Sqrt[a+b (x^4)]) (c+d (x^4))))dx  when b c-a d≠0

Derivation: Algebraic expansion

Basis: (1/(c+d (x^4)))==(1/(2 c (1-(Sqrt[-(d/c)]) (x^2))))+(1/(2 c (1+(Sqrt[-(d/c)]) (x^2))))

Rule 1.1.3.3.9.3.2.1: If  b c-a d≠0, then

∫(1/((Sqrt[a+b (x^4)]) (c+d (x^4))))dx  ⟶  (1/(2c))∫(1/((Sqrt[a+b (x^4)]) (1-(Sqrt[-(d/c)])(x^2))))dx+(1/(2c))∫(1/((Sqrt[a+b (x^4)]) (1+(Sqrt[-(d/c)])(x^2))))dx

Program code:

Int[1/(Sqrt[a_+b_.*x_^4]*(c_+d_.*x_^4)),x_Symbol] :=
  1/(2*c)*Int[1/(Sqrt[a+b*x^4]*(1-Rt[-d/c,2]*x^2)),x] + 1/(2*c)*Int[1/(Sqrt[a+b*x^4]*(1+Rt[-d/c,2]*x^2)),x] /;
FreeQ[{a,b,c,d},x] && NeQ[b*c-a*d,0]

2:  ∫(1/((((a+b (x^4)))^(3/4)) (c+d (x^4))))dx  when b c-a d≠0

Derivation: Algebraic expansion

Basis: ((((a+b z))^p)/(c+d z))==((b (((a+b z))^p))/(b c-a d))-((d (((a+b z))^(p+1)))/((b c-a d) (c+d z)))

Rule 1.1.3.3.9.3.2.2: If  b c-a d≠0, then

∫(1/((((a+b (x^4)))^(3/4)) (c+d (x^4))))dx  ⟶  (b/((b c-a d)))∫(1/(((a+b (x^4)))^(3/4)))dx-(d/((b c-a d)))∫((((a+b (x^4)))^(1/4))/(c+d (x^4)))dx

Program code:

Int[1/((a_+b_.*x_^4)^(3/4)*(c_+d_.*x_^4)),x_Symbol] :=
  b/(b*c-a*d)*Int[1/(a+b*x^4)^(3/4),x] - d/(b*c-a*d)*Int[(a+b*x^4)^(1/4)/(c+d*x^4),x] /;
FreeQ[{a,b,c,d},x] && NeQ[b*c-a*d,0]

4.  ∫((((a+b (x^3)))^p)/(c+d (x^3)))dx  when b c-a d≠0 ∧ b c+a d==0 ∧ p-(1/3)∈ℤ

1:  ∫((((a+b (x^3)))^(1/3))/(c+d (x^3)))dx  when b c-a d≠0 ∧ b c+a d==0

Derivation: Integration by substitution

Basis: If  b c+a d==0 , let q->((((b/a)))^(1/3)), then ((((a+b (x^3)))^(1/3))/(c+d (x^3)))==((9 a)/(c q)) Subst[(x/((4-a (x^3)) (1+2 a (x^3)))),x,(((1+q x))/(((a+b (x^3)))^(1/3)))] (∂_x)(((1+q x))/(((a+b (x^3)))^(1/3)))

Rule 1.1.3.3.9.4.1: If  b c-a d≠0 ∧ b c+a d==0 , let q->((((b/a)))^(1/3)), then

∫((((a+b (x^3)))^(1/3))/(c+d (x^3)))dx  ⟶  ((9 a)/(c q)) Subst[∫(x/((4-a (x^3)) (1+2 a (x^3))))dx,x,(((1+q x))/(((a+b (x^3)))^(1/3)))]

Program code:

Int[(a_+b_.*x_^3)^(1/3)/(c_+d_.*x_^3),x_Symbol] :=
  With[{q=Rt[b/a,3]},
  9*a/(c*q)*Subst[Int[x/((4-a*x^3)*(1+2*a*x^3)),x],x,(1+q*x)/(a+b*x^3)^(1/3)]] /;
FreeQ[{a,b,c,d},x] && NeQ[b*c-a*d,0] && EqQ[b*c+a*d,0]

2:  ∫(1/((((a+b (x^3)))^(2/3)) (c+d (x^3))))dx  when b c-a d≠0 ∧ b c+a d==0

Derivation: Algebraic expansion

Basis: (((a+b z))^p) (((c+d z))^q)==((b (((a+b z))^p) (((c+d z))^(q+1)))/(b c-a d))-((d (((a+b z))^(p+1)) (((c+d z))^q))/(b c-a d))

Rule 1.1.3.3.9.4.2: If  b c-a d≠0 ∧ b c+a d==0 , then

∫(1/((((a+b (x^3)))^(2/3)) (c+d (x^3))))dx  ⟶  (b/(b c-a d))∫(1/(((a+b (x^3)))^(2/3)))dx-(d/(b c-a d))∫((((a+b (x^3)))^(1/3))/(c+d (x^3)))dx

Program code:

Int[1/((a_+b_.*x_^3)^(2/3)*(c_+d_.*x_^3)),x_Symbol] :=
  b/(b*c-a*d)*Int[1/(a+b*x^3)^(2/3),x] - d/(b*c-a*d)*Int[(a+b*x^3)^(1/3)/(c+d*x^3),x] /;
FreeQ[{a,b,c,d},x] && NeQ[b*c-a*d,0] && EqQ[b*c+a*d,0]

10.  ∫(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when  b c-a d≠0 ∧ p<-1

1.  ∫(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when  b c-a d≠0 ∧ p<-1 ∧ q>0

1:  ∫((Sqrt[a+b (x^2)])/(((c+d (x^2)))^(3/2)))dx  when (b/a)>0 ∧ (d/c)>0

Derivation: Piecewise constant extraction

Basis: (∂_x)((Sqrt[a+b (x^2)])/((Sqrt[c+d (x^2)]) (Sqrt[((c (a+b (x^2)))/(a (c+d (x^2))))])))==0

Rule 1.1.3.3.10.1.1: If  (b/a)>0 ∧ (d/c)>0, then

∫((Sqrt[a+b (x^2)])/(((c+d (x^2)))^(3/2)))dx  ⟶  ((Sqrt[a+b (x^2)])/((Sqrt[c+d (x^2)]) (Sqrt[((c (a+b (x^2)))/(a (c+d (x^2))))]))) ∫((Sqrt[((c (a+b (x^2)))/(a (c+d (x^2))))])/(c+d (x^2)))dx  ⟶  ((Sqrt[a+b (x^2)])/(c (Sqrt[(d/c)]) (Sqrt[c+d (x^2)]) (Sqrt[((c (a+b (x^2)))/(a (c+d (x^2))))]))) EllipticE[ArcTan[(Sqrt[(d/c)]) x],1-((b c)/(a d))]

∫((Sqrt[a+b (x^2)])/(((c+d (x^2)))^(3/2)))dx  ⟶  ((a (Sqrt[c+d (x^2)]) (Sqrt[((c (a+b (x^2)))/(a (c+d (x^2))))]))/(c (Sqrt[a+b (x^2)]))) ∫((Sqrt[((c (a+b (x^2)))/(a (c+d (x^2))))])/(c+d (x^2)))dx  ⟶  ((a (Sqrt[c+d (x^2)]) (Sqrt[((c (a+b (x^2)))/(a (c+d (x^2))))]))/((c^2) (Sqrt[(d/c)]) (Sqrt[a+b (x^2)]))) EllipticE[ArcTan[(Sqrt[(d/c)]) x],1-((b c)/(a d))]

Program code:

Int[Sqrt[a_+b_.*x_^2]/(c_+d_.*x_^2)^(3/2),x_Symbol] :=
  Sqrt[a+b*x^2]/(c*Rt[d/c,2]*Sqrt[c+d*x^2]*Sqrt[c*(a+b*x^2)/(a*(c+d*x^2))])*EllipticE[ArcTan[Rt[d/c,2]*x],1-b*c/(a*d)] /;
FreeQ[{a,b,c,d},x] && PosQ[b/a] && PosQ[d/c]

(* Int[Sqrt[a_+b_.*x_^2]/(c_+d_.*x_^2)^(3/2),x_Symbol] :=
  a*Sqrt[c+d*x^2]*Sqrt[(c*(a+b*x^2))/(a*(c+d*x^2))]/(c^2*Rt[d/c,2]*Sqrt[a+b*x^2])*EllipticE[ArcTan[Rt[d/c,2]*x],1-b*c/(a*d)] /;
FreeQ[{a,b,c,d},x] && PosQ[b/a] && PosQ[d/c] *)

2:  ∫(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when b c-a d≠0 ∧ p<-1 ∧ 0<q<1

Derivation: Binomial product recurrence 1 with A=1 and B=0

Rule 1.1.3.3.10.1.2: If  b c-a d≠0 ∧ p<-1 ∧ 0<q<1, then

∫(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  -((x (((a+b (x^n)))^(p+1))(((c+d (x^n)))^q))/(a n(p+1)))+
(1/(a n(p+1)))∫(((a+b (x^n)))^(p+1))(((c+d (x^n)))^(q-1)) (c(n(p+1)+1)+d(n (p+q+1)+1)(x^n))dx

Program code:

Int[(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  -x*(a+b*x^n)^(p+1)*(c+d*x^n)^q/(a*n*(p+1)) + 
  1/(a*n*(p+1))*Int[(a+b*x^n)^(p+1)*(c+d*x^n)^(q-1)*Simp[c*(n*(p+1)+1)+d*(n*(p+q+1)+1)*x^n,x],x] /;
FreeQ[{a,b,c,d,n},x] && NeQ[b*c-a*d,0] && LtQ[p,-1] && LtQ[0,q,1] && IntBinomialQ[a,b,c,d,n,p,q,x]

3:  ∫(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when b c-a d≠0 ∧ p<-1 ∧ q>1

Derivation: Binomial product recurrence 1 with A=c, B=d and q=q-1

Rule 1.1.3.3.10.1.3: If  b c-a d≠0 ∧ p<-1 ∧ q>1, then

∫(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  (((a d-b c)x (((a+b (x^n)))^(p+1))(((c+d (x^n)))^(q-1)))/(a b n(p+1)))- 
(1/(a b n(p+1)))∫(((a+b (x^n)))^(p+1))(((c+d (x^n)))^(q-2)) (c (a d-b c (n(p+1)+1))+d (a d (n (q-1)+1)-b c(n (p+q)+1))(x^n))dx

Program code:

Int[(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  (a*d-c*b)*x*(a+b*x^n)^(p+1)*(c+d*x^n)^(q-1)/(a*b*n*(p+1)) - 
  1/(a*b*n*(p+1))*
    Int[(a+b*x^n)^(p+1)*(c+d*x^n)^(q-2)*Simp[c*(a*d-c*b*(n*(p+1)+1))+d*(a*d*(n*(q-1)+1)-b*c*(n*(p+q)+1))*x^n,x],x] /;
FreeQ[{a,b,c,d,n},x] && NeQ[b*c-a*d,0] && LtQ[p,-1] && GtQ[q,1] && IntBinomialQ[a,b,c,d,n,p,q,x]

2:  ∫(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when b c-a d≠0 ∧ p<-1

Derivation: Binomial product recurrence 2a with A=1 and B=0

Rule 1.1.3.3.10.1.2: If  b c-a d≠0 ∧ p<-1, then

∫(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  -((b x (((a+b (x^n)))^(p+1))(((c+d (x^n)))^(q+1)))/(a n(p+1)(b c-a d)))+ 
(1/(a n(p+1)(b c-a d)))∫(((a+b (x^n)))^(p+1))(((c+d (x^n)))^q) (b c+n(p+1)(b c-a d)+d b (n (p+q+2)+1) (x^n))dx

Program code:

Int[(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  -b*x*(a+b*x^n)^(p+1)*(c+d*x^n)^(q+1)/(a*n*(p+1)*(b*c-a*d)) + 
  1/(a*n*(p+1)*(b*c-a*d))*
    Int[(a+b*x^n)^(p+1)*(c+d*x^n)^q*Simp[b*c+n*(p+1)*(b*c-a*d)+d*b*(n*(p+q+2)+1)*x^n,x],x] /;
FreeQ[{a,b,c,d,n,q},x] && NeQ[b*c-a*d,0] && LtQ[p,-1] && Not[Not[IntegerQ[p]] && IntegerQ[q] && LtQ[q,-1]] && 
  IntBinomialQ[a,b,c,d,n,p,q,x]

11:  ∫(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when b c-a d ≠0 ∧ n∈(SuperPlus[ℤ])∧ p∈ℤ ∧ q∈ℤ ∧ p+q>0

Derivation: Algebraic expansion

Rule 1.1.3.3.11: If  b c-a d ≠0 ∧ n∈(SuperPlus[ℤ])∧ p∈ℤ ∧ q∈ℤ ∧ p+q>0, then

∫(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  ∫ExpandIntegrand[(((a+b (x^n)))^p) (((c+d (x^n)))^q),x]dx

Program code:

Int[(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  Int[ExpandIntegrand[(a+b*x^n)^p*(c+d*x^n)^q,x],x] /;
FreeQ[{a,b,c,d},x] && NeQ[b*c-a*d,0] && IGtQ[n,0] && IntegersQ[p,q] && GtQ[p+q,0]

12.  ∫(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when  b c-a d≠0 ∧ q>0

1:  ∫(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when b c-a d≠0 ∧ q>1 ∧ n (p+q)+1≠0

Derivation: Binomial product recurrence 3a with A=c, B=d and q=q-1

Rule 1.1.3.3.12.1: If  b c-a d≠0 ∧ q>1 ∧ n (p+q)+1≠0, then

∫(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  ((d x (((a+b (x^n)))^(p+1))(((c+d (x^n)))^(q-1)))/(b (n (p+q)+1)))+ 
(1/(b (n (p+q)+1)))∫(((a+b (x^n)))^p)(((c+d (x^n)))^(q-2)) (c(b c(n (p+q)+1)-a d)+d(b c (n (p+2 q-1)+1)-a d(n(q-1)+1)) (x^n))dx

Program code:

Int[(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  d*x*(a+b*x^n)^(p+1)*(c+d*x^n)^(q-1)/(b*(n*(p+q)+1)) + 
  1/(b*(n*(p+q)+1))*
    Int[(a+b*x^n)^p*(c+d*x^n)^(q-2)*Simp[c*(b*c*(n*(p+q)+1)-a*d)+d*(b*c*(n*(p+2*q-1)+1)-a*d*(n*(q-1)+1))*x^n,x],x] /;
FreeQ[{a,b,c,d,n,p},x] && NeQ[b*c-a*d,0] && GtQ[q,1] && NeQ[n*(p+q)+1,0] && Not[IGtQ[p,1]] && IntBinomialQ[a,b,c,d,n,p,q,x]

2:  ∫(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when b c-a d≠0 ∧ q>0 ∧ p>0

Derivation: Binomial product recurrence 2b with m=0, A=a, B=b and p=p-1

Rule 1.1.3.3.12.2: If  b c-a d≠0 ∧ q>0 ∧ p>0, then

∫(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  
((x (((a+b (x^n)))^p) (((c+d (x^n)))^q))/(n (p+q)+1))+(n/(n (p+q)+1))∫(((a+b (x^n)))^(p-1)) (((c+d (x^n)))^(q-1)) (a c(p+q)+(q(b c-a d)+a d(p+q)) (x^n))dx

Program code:

Int[(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  x*(a+b*x^n)^p*(c+d*x^n)^q/(n*(p+q)+1) + 
  n/(n*(p+q)+1)*Int[(a+b*x^n)^(p-1)*(c+d*x^n)^(q-1)*Simp[a*c*(p+q)+(q*(b*c-a*d)+a*d*(p+q))*x^n,x],x] /;
FreeQ[{a,b,c,d,n},x] && NeQ[b*c-a*d,0] && GtQ[q,0] && GtQ[p,0] && IntBinomialQ[a,b,c,d,n,p,q,x]

13.  ∫((((a+b (x^2)))^p)/(Sqrt[c+d (x^2)]))dx  when b c-a d≠0 ∧ (p^2)==(1/4)

1.  ∫(1/((Sqrt[a+b (x^2)]) (Sqrt[c+d (x^2)])))dx  when b c-a d≠0

1:  ∫(1/((Sqrt[a+b (x^2)]) (Sqrt[c+d (x^2)])))dx  when (d/c)>0 ∧ (b/a)>0

Derivation: Piecewise constant extraction

Basis: (∂_x)(((Sqrt[c+d (x^2)]) (Sqrt[((c (a+b (x^2)))/(a (c+d (x^2))))]))/(Sqrt[a+b (x^2)]))==0

Rule 1.1.3.3.13.1.1: If  (d/c)>0 ∧ (b/a)>0, then

∫(1/((Sqrt[a+b (x^2)]) (Sqrt[c+d (x^2)])))dx  ⟶  ((Sqrt[a+b (x^2)])/((Sqrt[c+d (x^2)]) (Sqrt[((c (a+b (x^2)))/(a (c+d (x^2))))]))) ∫((Sqrt[((c (a+b (x^2)))/(a (c+d (x^2))))])/(a+b (x^2)))dx  ⟶  ((Sqrt[a+b (x^2)])/(a (Sqrt[(d/c)]) (Sqrt[c+d (x^2)]) (Sqrt[((c (a+b (x^2)))/(a (c+d (x^2))))]))) EllipticF[ArcTan[(Sqrt[(d/c)]) x],1-((b c)/(a d))]

∫(1/((Sqrt[a+b (x^2)]) (Sqrt[c+d (x^2)])))dx  ⟶  ((a (Sqrt[c+d (x^2)]) (Sqrt[((c (a+b (x^2)))/(a (c+d (x^2))))]))/(c (Sqrt[a+b (x^2)]))) ∫((Sqrt[((c (a+b (x^2)))/(a (c+d (x^2))))])/(a+b (x^2)))dx  ⟶  (((Sqrt[c+d (x^2)]) (Sqrt[((c (a+b (x^2)))/(a (c+d (x^2))))]))/(c (Sqrt[(d/c)]) (Sqrt[a+b (x^2)]))) EllipticF[ArcTan[(Sqrt[(d/c)]) x],1-((b c)/(a d))]

Program code:

Int[1/(Sqrt[a_+b_.*x_^2]*Sqrt[c_+d_.*x_^2]),x_Symbol] :=
  Sqrt[a+b*x^2]/(a*Rt[d/c,2]*Sqrt[c+d*x^2]*Sqrt[c*(a+b*x^2)/(a*(c+d*x^2))])*EllipticF[ArcTan[Rt[d/c,2]*x],1-b*c/(a*d)] /;
FreeQ[{a,b,c,d},x] && PosQ[d/c] && PosQ[b/a] && Not[SimplerSqrtQ[b/a,d/c]]

(* Int[1/(Sqrt[a_+b_.*x_^2]*Sqrt[c_+d_.*x_^2]),x_Symbol] :=
  Sqrt[c+d*x^2]*Sqrt[c*(a+b*x^2)/(a*(c+d*x^2))]/(c*Rt[d/c,2]*Sqrt[a+b*x^2])*EllipticF[ArcTan[Rt[d/c,2]*x],1-b*c/(a*d)] /;
FreeQ[{a,b,c,d},x] && PosQ[d/c] && PosQ[b/a] && Not[SimplerSqrtQ[b/a,d/c]] *)

2.  ∫(1/((Sqrt[a+b (x^2)]) (Sqrt[c+d (x^2)])))dx  when (d/c)≯0

1:  ∫(1/((Sqrt[a+b (x^2)]) (Sqrt[c+d (x^2)])))dx  when (d/c)≯0 ∧ c>0 ∧ a>0

Rule 1.1.3.3.13.1.2.1: If  (d/c)≯0 ∧ c>0 ∧ a>0, then

∫(1/((Sqrt[a+b (x^2)]) (Sqrt[c+d (x^2)])))dx  ⟶  (1/((Sqrt[a])(Sqrt[c]) (Sqrt[-(d/c)])))  EllipticF[ArcSin[(Sqrt[-(d/c)]) x],((b c)/(a d))]

Program code:

Int[1/(Sqrt[a_+b_.*x_^2]*Sqrt[c_+d_.*x_^2]),x_Symbol] :=
  1/(Sqrt[a]*Sqrt[c]*Rt[-d/c,2])*EllipticF[ArcSin[Rt[-d/c,2]*x],b*c/(a*d)] /;
FreeQ[{a,b,c,d},x] && NegQ[d/c] && GtQ[c,0] && GtQ[a,0] && Not[NegQ[b/a] && SimplerSqrtQ[-b/a,-d/c]]

2:  ∫(1/((Sqrt[a+b (x^2)]) (Sqrt[c+d (x^2)])))dx  when (d/c)≯0 ∧ c>0 ∧ a-((b c)/d)>0

Rule 1.1.3.3.13.1.2.2: If (d/c)≯0 ∧ c>0 ∧ a-((b c)/d)>0, then

∫(1/((Sqrt[a+b (x^2)]) (Sqrt[c+d (x^2)])))dx  ⟶  -(1/((Sqrt[c]) (Sqrt[-(d/c)]) (Sqrt[a-((b c)/d)])))EllipticF[ArcCos[(Sqrt[-(d/c)]) x],((b c)/(b c-a d))]

Program code:

Int[1/(Sqrt[a_+b_.*x_^2]*Sqrt[c_+d_.*x_^2]),x_Symbol] :=
  -1/(Sqrt[c]*Rt[-d/c,2]*Sqrt[a-b*c/d])*EllipticF[ArcCos[Rt[-d/c,2]*x],b*c/(b*c-a*d)] /;
FreeQ[{a,b,c,d},x] && NegQ[d/c] && GtQ[c,0] && GtQ[a-b*c/d,0]

3:  ∫(1/((Sqrt[a+b (x^2)]) (Sqrt[c+d (x^2)])))dx  when (d/c)≯0 ∧ c≯0

Derivation: Piecewise constant extraction

Basis: (∂_x)((Sqrt[1+(d/c) (x^2)])/(Sqrt[c+d (x^2)]))=0

Rule 1.1.3.3.13.1.2.3: If  (d/c)≯0 ∧ c≯0, then

∫(1/((Sqrt[a+b (x^2)]) (Sqrt[c+d (x^2)])))dx  ⟶  ((Sqrt[1+(d/c) (x^2)])/(Sqrt[c+d (x^2)]))∫(1/((Sqrt[a+b (x^2)]) (Sqrt[1+(d/c) (x^2)])))dx

Program code:

Int[1/(Sqrt[a_+b_.*x_^2]*Sqrt[c_+d_.*x_^2]),x_Symbol] :=
  Sqrt[1+d/c*x^2]/Sqrt[c+d*x^2]*Int[1/(Sqrt[a+b*x^2]*Sqrt[1+d/c*x^2]),x] /;
FreeQ[{a,b,c,d},x] && Not[GtQ[c,0]]

2.  ∫((Sqrt[a+b (x^2)])/(Sqrt[c+d (x^2)]))dx  when b c-a d≠0

1.  ∫((Sqrt[a+b (x^2)])/(Sqrt[c+d (x^2)]))dx  when (d/c)>0

1:  ∫((Sqrt[a+b (x^2)])/(Sqrt[c+d (x^2)]))dx  when (d/c)>0 ∧ (b/a)>0

Derivation: Algebraic expansion

Basis: (Sqrt[a+b (x^2)])==(a/(Sqrt[a+b (x^2)]))+((b (x^2))/(Sqrt[a+b (x^2)]))

Rule 1.1.3.3.13.2.1.1: If  (d/c)>0 ∧ (b/a)>0, then

∫((Sqrt[a+b (x^2)])/(Sqrt[c+d (x^2)]))dx  ⟶  a ∫(1/((Sqrt[a+b (x^2)]) (Sqrt[c+d (x^2)])))dx+b ∫((x^2)/((Sqrt[a+b (x^2)]) (Sqrt[c+d (x^2)])))dx

Program code:

Int[Sqrt[a_+b_.*x_^2]/Sqrt[c_+d_.*x_^2],x_Symbol] :=
  a*Int[1/(Sqrt[a+b*x^2]*Sqrt[c+d*x^2]),x] + b*Int[x^2/(Sqrt[a+b*x^2]*Sqrt[c+d*x^2]),x] /;
FreeQ[{a,b,c,d},x] && PosQ[d/c] && PosQ[b/a]

2:  ∫((Sqrt[a+b (x^2)])/(Sqrt[c+d (x^2)]))dx  when (d/c)>0 ∧ (b/a)≯0

Derivation: Algebraic expansion

Basis: ((Sqrt[a+b (x^2)])/(Sqrt[c+d (x^2)]))==((b (Sqrt[c+d (x^2)]))/(d (Sqrt[a+b (x^2)])))-((b c-a d)/(d (Sqrt[a+b (x^2)]) (Sqrt[c+d (x^2)])))

Rule 1.1.3.3.13.2.1.2: If  (d/c)>0 ∧ (b/a)≯0, then

∫((Sqrt[a+b (x^2)])/(Sqrt[c+d (x^2)]))dx  ⟶  (b/d) ∫((Sqrt[c+d (x^2)])/(Sqrt[a+b (x^2)]))dx-((b c-a d)/d) ∫(1/((Sqrt[a+b (x^2)]) (Sqrt[c+d (x^2)])))dx

Program code:

Int[Sqrt[a_+b_.*x_^2]/Sqrt[c_+d_.*x_^2],x_Symbol] :=
  b/d*Int[Sqrt[c+d*x^2]/Sqrt[a+b*x^2],x] - (b*c-a*d)/d*Int[1/(Sqrt[a+b*x^2]*Sqrt[c+d*x^2]),x] /;
FreeQ[{a,b,c,d},x] && PosQ[d/c] && NegQ[b/a]

2.  ∫((Sqrt[a+b (x^2)])/(Sqrt[c+d (x^2)]))dx  when (d/c)≯0

1.  ∫((Sqrt[a+b (x^2)])/(Sqrt[c+d (x^2)]))dx  when (d/c)≯0 ∧ c>0

1:  ∫((Sqrt[a+b (x^2)])/(Sqrt[c+d (x^2)]))dx  when (d/c)≯0 ∧ c>0 ∧ a>0

Rule 1.1.3.3.13.2.2.1.1: If  (d/c)≯0 ∧ c>0 ∧ a>0, then

∫((Sqrt[a+b (x^2)])/(Sqrt[c+d (x^2)]))dx  ⟶  ((Sqrt[a])/((Sqrt[c])(Sqrt[-(d/c)])))EllipticE[ArcSin[(Sqrt[-(d/c)]) x],((b c)/(a d))]

Program code:

Int[Sqrt[a_+b_.*x_^2]/Sqrt[c_+d_.*x_^2],x_Symbol] :=
  Sqrt[a]/(Sqrt[c]*Rt[-d/c,2])*EllipticE[ArcSin[Rt[-d/c,2]*x],b*c/(a*d)] /;
FreeQ[{a,b,c,d},x] && NegQ[d/c] && GtQ[c,0] && GtQ[a,0]

2:  ∫((Sqrt[a+b (x^2)])/(Sqrt[c+d (x^2)]))dx  when (d/c)≯0 ∧ c>0 ∧ a-((b c)/d)>0

Rule 1.1.3.3.13.2.2.1.2: If (d/c)≯0 ∧ c>0 ∧ a-((b c)/d)>0, then

∫((Sqrt[a+b (x^2)])/(Sqrt[c+d (x^2)]))dx  ⟶  -((Sqrt[a-((b c)/d)])/((Sqrt[c]) (Sqrt[-(d/c)])))EllipticE[ArcCos[(Sqrt[-(d/c)]) x],((b c)/(b c-a d))]

Program code:

Int[Sqrt[a_+b_.*x_^2]/Sqrt[c_+d_.*x_^2],x_Symbol] :=
  -Sqrt[a-b*c/d]/(Sqrt[c]*Rt[-d/c,2])*EllipticE[ArcCos[Rt[-d/c,2]*x],b*c/(b*c-a*d)] /;
FreeQ[{a,b,c,d},x] && NegQ[d/c] && GtQ[c,0] && GtQ[a-b*c/d,0]

3:  ∫((Sqrt[a+b (x^2)])/(Sqrt[c+d (x^2)]))dx  when (d/c)≯0 ∧ c>0 ∧ a≯0

Derivation: Piecewise constant extraction

Basis: (∂_x)((Sqrt[a+b (x^2)])/(Sqrt[1+(b/a) (x^2)]))==0

Rule 1.1.3.3.13.2.2.1.3: If  (d/c)≯0 ∧ c>0 ∧ a≯0, then

∫((Sqrt[a+b (x^2)])/(Sqrt[c+d (x^2)]))dx  ⟶  (((Sqrt[a+b (x^2)]) )/(Sqrt[1+(b/a) (x^2)]))∫((Sqrt[1+(b/a) (x^2)])/(Sqrt[c+d (x^2)]))dx

Program code:

Int[Sqrt[a_+b_.*x_^2]/Sqrt[c_+d_.*x_^2],x_Symbol] :=
  Sqrt[a+b*x^2]/Sqrt[1+b/a*x^2]*Int[Sqrt[1+b/a*x^2]/Sqrt[c+d*x^2],x] /;
FreeQ[{a,b,c,d},x] && NegQ[d/c] && GtQ[c,0] && Not[GtQ[a,0]]

2:  ∫((Sqrt[a+b (x^2)])/(Sqrt[c+d (x^2)]))dx  when (d/c)≯0 ∧ c≯0

Derivation: Piecewise constant extraction

Basis: (∂_x)(((Sqrt[1+(d/c) (x^2)]) )/(Sqrt[c+d (x^2)]))==0

Rule 1.1.3.3.13.2.2.2: If  (d/c)≯0 ∧ c≯0, then

∫((Sqrt[a+b (x^2)])/(Sqrt[c+d (x^2)]))dx  ⟶  (((Sqrt[1+(d/c) (x^2)]) )/(Sqrt[c+d (x^2)]))∫((Sqrt[a+b (x^2)])/(Sqrt[1+(d/c) (x^2)]))dx

Program code:

Int[Sqrt[a_+b_.*x_^2]/Sqrt[c_+d_.*x_^2],x_Symbol] :=
  Sqrt[1+d/c*x^2]/Sqrt[c+d*x^2]*Int[Sqrt[a+b*x^2]/Sqrt[1+d/c*x^2],x] /;
FreeQ[{a,b,c,d},x] && NegQ[d/c] && Not[GtQ[c,0]]

14:  ∫(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when b c-a d ≠0 ∧ p∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule 1.1.3.3.14: If  b c-a d ≠0 ∧ p∈(SuperPlus[ℤ]), then

∫(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  ∫ExpandIntegrand[(((a+b (x^n)))^p) (((c+d (x^n)))^q),x]dx

Program code:

Int[(a_+b_.*x_^n_)^p_.*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  Int[ExpandIntegrand[(a+b*x^n)^p*(c+d*x^n)^q,x],x] /;
FreeQ[{a,b,c,d,n,q},x] && NeQ[b*c-a*d,0] && IGtQ[p,0]

A.  ∫(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when b c-a d≠0 ∧ n≠-1

1:  ∫(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when  b c-a d≠0 ∧ n≠-1 ∧ (p∈ℤ ∨ a>0) ∧ (q∈ℤ ∨ c>0)

Rule 1.1.3.3.A.1: If  b c-a d≠0 ∧ n≠-1 ∧ (p∈ℤ ∨ a>0) ∧ (q∈ℤ ∨ c>0), then

∫(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  (a^p) (c^q) x AppellF1[(1/n),-p,-q,1+(1/n),-((b (x^n))/a),-((d (x^n))/c)]

Program code:

Int[(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  a^p*c^q*x*AppellF1[1/n,-p,-q,1+1/n,-b*x^n/a,-d*x^n/c] /;
FreeQ[{a,b,c,d,n,p,q},x] && NeQ[b*c-a*d,0] && NeQ[n,-1] && (IntegerQ[p] || GtQ[a,0]) && (IntegerQ[q] || GtQ[c,0])

2:  ∫(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  when  b c-a d≠0 ∧ n≠-1 ∧ ¬(p∈ℤ ∨ a>0)

Derivation: Piecewise constant extraction

Basis: (∂_x)((((a+b (x^n)))^p)/(((1+((b (x^n))/a)))^p))==0

Rule 1.1.3.3.A.2: If  b c-a d≠0 ∧ n≠-1 ∧ ¬(p∈ℤ ∨ a>0), then

∫(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx  ⟶  (((a^(IntPart[p])) (((a+b (x^n)))^(FracPart[p])))/( (((1+((b (x^n))/a)))^(FracPart[p])))) ∫(((1+((b (x^n))/a)))^p) (((c+d (x^n)))^q)dx

Program code:

Int[(a_+b_.*x_^n_)^p_*(c_+d_.*x_^n_)^q_,x_Symbol] :=
  a^IntPart[p]*(a+b*x^n)^FracPart[p]/(1+b*x^n/a)^FracPart[p]*Int[(1+b*x^n/a)^p*(c+d*x^n)^q,x] /;
FreeQ[{a,b,c,d,n,p,q},x] && NeQ[b*c-a*d,0] && NeQ[n,-1] && Not[IntegerQ[p] || GtQ[a,0]]

S:  ∫(((a+b (u^n)))^p) (((c+d (u^n)))^q)dx  when  u==e+f x

Derivation: Integration by substitution

Rule 1.1.3.3.S: If  u==e+f x, then

∫(((a+b (u^n)))^p) (((c+d (u^n)))^q)dx  ⟶  (1/f)Subst[∫(((a+b (x^n)))^p) (((c+d (x^n)))^q)dx,x,u]

Program code:

Int[(a_.+b_.*u_^n_)^p_.*(c_.+d_.*u_^n_)^q_.,x_Symbol] :=
  1/Coefficient[u,x,1]*Subst[Int[(a+b*x^n)^p*(c+d*x^n)^q,x],x,u] /;
FreeQ[{a,b,c,d,n,p,q},x] && LinearQ[u,x] && NeQ[u,x]

N:  ∫((Subscript[P, x])^p)((Subscript[Q, x])^q)dx  when  (Subscript[P, x])==a+b (((e+f x))^n) ∧ (Subscript[Q, x])==c+d (((e+f x))^n)

Derivation: Algebraic normalization

Rule 1.1.3.3.N: If  (Subscript[P, x])==a+b (((e+f x))^n) ∧ (Subscript[Q, x])==c+d (((e+f x))^n), then

∫((Subscript[P, x])^p)((Subscript[Q, x])^q)dx  ⟶  ∫(((a+b (((e+f x))^n)))^p)(((c+d (((e+f x))^n)))^q)dx

Program code:

Int[u_^p_.*v_^q_.,x_Symbol] :=
  Int[NormalizePseudoBinomial[u,x]^p*NormalizePseudoBinomial[v,x]^q,x] /;
FreeQ[{p,q},x] && PseudoBinomialPairQ[u,v,x]

Int[x_^m_.*u_^p_.*v_^q_.,x_Symbol] :=
  Int[NormalizePseudoBinomial[x^(m/p)*u,x]^p*NormalizePseudoBinomial[v,x]^q,x] /;
FreeQ[{p,q},x] && IntegersQ[p,m/p] && PseudoBinomialPairQ[x^(m/p)*u,v,x]

(* IntBinomialQ[a,b,c,d,n,p,q,x] returns True iff (a+b*x^n)^p*(c+d*x^n)^q is integrable wrt x in terms of non-Appell functions. *)
IntBinomialQ[a_,b_,c_,d_,n_,p_,q_,x_Symbol] :=
  IntegersQ[p,q] || IGtQ[p,0] || IGtQ[q,0] || 
  (EqQ[n,2] || EqQ[n,4]) && (IntegersQ[p,4*q] || IntegersQ[4*p,q]) || 
  EqQ[n,2] && (IntegersQ[2*p,2*q] || IntegersQ[3*p,q] && EqQ[b*c+3*a*d,0] || IntegersQ[p,3*q] && EqQ[3*b*c+a*d,0]) || 
  EqQ[n,3] && (IntegersQ[p+1/3,q] || IntegersQ[q+1/3,p]) || 
  EqQ[n,3] && (IntegersQ[p+2/3,q] || IntegersQ[q+2/3,p]) && EqQ[b*c+a*d,0]

Rules for integrands of the form(((a+b (x^n)))^p) (((c+d (x^(-n))))^q)

1:  ∫(((a+b (x^n)))^p) (((c+d (x^(-n))))^q)dx  when  q∈ℤ

Derivation: Algebraic normalization

Basis: If  q∈ℤ, then  (((c+d (x^(-n))))^q)==((((d+c (x^n)))^q)/(x^(n q)))

Rule 1.1.3.3.15.1: If  q∈ℤ, then

∫(((a+b (x^n)))^p) (((c+d (x^(-n))))^q)dx  ⟶  ∫(((((a+b (x^n)))^p) (((d+c (x^n)))^q))/(x^(n q)))dx

Program code:

Int[(a_+b_.*x_^n_.)^p_.*(c_+d_.*x_^mn_.)^q_.,x_Symbol] :=
  Int[(a+b*x^n)^p*(d+c*x^n)^q/x^(n*q),x] /;
FreeQ[{a,b,c,d,n,p},x] && EqQ[mn,-n] && IntegerQ[q] && (PosQ[n] || Not[IntegerQ[p]])

2:  ∫(((a+b (x^n)))^p) (((c+d (x^(-n))))^q)dx  when  q∉ℤ ∧ p∉ℤ

Derivation: Piecewise constant extraction

Basis: (∂_x)(((x^(n q)) (((c+d (x^(-n))))^q))/(((d+c (x^n)))^q))==0

Basis: (((x^(n q)) (((c+d (x^(-n))))^q))/(((d+c (x^n)))^q))==(((x^(n FracPart[q])) (((c+d (x^(-n))))^(FracPart[q])))/(((d+c (x^n)))^(FracPart[q])))

Rule 1.1.3.3.15.2: If  q∉ℤ ∧ p∉ℤ, then

∫(((a+b (x^n)))^p) (((c+d (x^(-n))))^q)dx  ⟶  (((x^(n FracPart[q])) (((c+d (x^(-n))))^(FracPart[q])))/(((d+c (x^n)))^(FracPart[q]))) ∫(((((a+b (x^n)))^p) (((d+c (x^n)))^q))/(x^(n q)))dx

Program code:

Int[(a_+b_.*x_^n_.)^p_*(c_+d_.*x_^mn_.)^q_,x_Symbol] :=
  x^(n*FracPart[q])*(c+d*x^(-n))^FracPart[q]/(d+c*x^n)^FracPart[q]*Int[(a+b*x^n)^p*(d+c*x^n)^q/x^(n*q),x] /;
FreeQ[{a,b,c,d,n,p,q},x] && EqQ[mn,-n] && Not[IntegerQ[q]] && Not[IntegerQ[p]]